易语言中”如果“”如果真“”判断“这3个句子有什么不同，请举例子！”结束“”销毁“这2个有什么不同请

.版本 2

.程序集 窗口程序集1, , , 在启动窗口添加三个按钮，分别命名为：如果真_按钮、如果_按钮、判断_按钮，在窗口空白处双击，将这里的全部代码粘贴到窗口程序集1，运行程序测试

.子程序 如果真_举例, , , 只需要对单个条件进行处理
.局部变量 输入内容, 文本型

输入框 (“请输入一个数字！”, , “1”, 输入内容, #输入整数)
.如果真 (输入内容 ＝ “1”)
' 输入内容是数字1时窗口移到屏幕最左边
_启动窗口.左边 ＝ 0
.如果真结束

.子程序 如果_举例, , , 需要对条件成立、不成立分别处理
.局部变量 输入内容, 文本型

输入框 (“请输入一个数字！”, , “1”, 输入内容, #输入整数)
.如果 (输入内容 ＝ “1”)
' 输入内容是数字1时窗口移到屏幕最左边
_启动窗口.左边 ＝ 0
.否则
' 输入内容不是数字1时窗口移到屏幕最右边
_启动窗口.左边 ＝ 取屏幕宽度 () － _启动窗口.宽度

.如果结束

.子程序 判断_举例, , , 需要对多个条件进行处理
.局部变量 输入内容, 文本型

输入框 (“请输入一个数字！”, , “1”, 输入内容, #输入整数)
.判断开始 (输入内容 ＝ “1”)
' 输入内容是数字1时窗口移到屏幕最左边
_启动窗口.左边 ＝ 0
.判断 (输入内容 ＝ “2”)
' 输入内容是数字2时窗口移到屏幕最右边
_启动窗口.左边 ＝ 取屏幕宽度 () － _启动窗口.宽度
.判断 (输入内容 ＝ “3”)
' 输入内容是数字3时窗口移到屏幕中间、上方,
_启动窗口.左边 ＝ (取屏幕宽度 () － _启动窗口.宽度) ÷ 2
_启动窗口.顶边 ＝ 0
.判断 (输入内容 ＝ “4”)
' 输入内容是数字3时窗口移到屏幕中间、下方,
_启动窗口.左边 ＝ (取屏幕宽度 () － _启动窗口.宽度) ÷ 2
_启动窗口.顶边 ＝ 取屏幕高度 () － _启动窗口.高度
.默认

.判断结束

.子程序 _如果真_按钮_被单击

如果真_举例 ()

.子程序 _如果_按钮_被单击

如果_举例 ()

.子程序 _判断_按钮_被单击

判断_举例 ()

给你的说的通俗一点:

======================================
—如果真(这里是条件)
|条件满足时进入这里
↓
上边的执行完毕后会进入这里的语句(不论是否满足条件)
=====================================

—如果(这里是条件)
|—条件满足后会进入这里的语句
|→条件不满足会进入这里的语句
↓
上边的执行完毕后会进入这里的语句(不论是否满足条件)
===================================
判断()
与如果类似,但是多用于大于两个条件的判断,这种情况用判断()的话可读性好.

======================================
销毁()
销毁这个程序集想对应的窗口(或者你在销毁命令中写的窗口,比如:_启动窗口.销毁()就是指定销毁_启动窗口),也就是关闭某某窗口的意思

=========================================
结束()
将包含了该结束语句的易语言程序关闭,就是把你的易程序完全退出

1) 如果真 多用于单条件判断,这样代码比较简洁,而且在大,中型程序中可以节省很多代码;

2) 如果 多用于双条件判断.

3) 判断 多用于大于两个条件的判断,使用代码可读性好.